home *** CD-ROM | disk | FTP | other *** search
/ FishMarket 1.0 / FishMarket v1.0.iso / fishies / 526-550 / disk_543 / td / td.asm < prev    next >
Assembly Source File  |  1992-05-06  |  12KB  |  450 lines
  1. *    TD
  2. *    By Preben Nielsen
  3. *
  4. *    Based on 'TrackDisplay' on Fish-disk 399 by Olaf Barthel.
  5. *
  6. *      TD is a program that continuously monitors and displays
  7. *    the current track for each connected floppy disk.
  8. *
  9. *      The size of the window and the use of colors in it depends on
  10. *    the version of the Kickstart/Workbench (1.2/1.3 vs. 2.?).
  11. *
  12. *    NOTE:    There's no need to 'RUN' or 'RUNBACK' this program from the
  13. *        CLI. It is auto-detaching.
  14. *
  15. *HISTORY
  16. *          Made with Hisoft V2.12
  17. * 
  18. *           January: Recieved 'Trackdisplay' on Fish-disk 399.
  19. *                    Nice program Olaf. Thanks.
  20. *
  21. *  V1.0   03-Mar-91: First working version.
  22. *         04-Mar-91: Added auto-detaching code.
  23. *         07-Mar-91: Uses 'PrintIText' instead of 'Move'/'Text'. Because of
  24. *                    this, my version used nearly twice the amount of
  25. *                    processor-time as the original (according to Xoper).
  26. *         15-Mar-91: Now uses 'Move'/'Text'. Code is now larger but faster.
  27. *         19-Apr-91: Made some modifications to make it look better
  28. *                    under WB2.0 (haven't actually tried it yet)
  29. *  V1.1   02-Aug-91: Damned - why didn't anyone tell me that TD looked
  30. *                    awful (strange) under kickstart 1.3. It thought it
  31. *                    it was running under kickstart 2.x, and therefore
  32. *                    changed its own appearance ! Not only didn't it look
  33. *                    good - it also didn't work correctly as a trackdisplay
  34. *                    because of differences between 1.3 and 2.x. Well, all
  35. *                    that has been fixed now. TD looks a lot better than the
  36. *                    original 'TrackDisplay' when running under 2.x.
  37. *         08-Aug-91: Now the opened window is as high as the dragbar of
  38. *                    all the other windows on the WB-screen.
  39. *  V2.0   09-Aug-91: Now TD only shows the drives which are available.
  40. *         22-Aug-91: Now TD can perfecty emulate the 2.x way of using
  41. *                    colors in windows.
  42.  
  43.     OPT O+
  44.     OPT O1+            ; Tells when a branch could be optimised to short
  45.     OPT i+            ; Tells when '#' is probably missing
  46.  
  47.         incdir        "AsmInc:"
  48.         include        "P.i"
  49.         include        "Detach.i"
  50.         include        "relMacros.i"
  51.         include        "exec/exec_lib.i"
  52.         include        "exec/memory.i"
  53.         include        "exec/interrupts.i"
  54.         include        "exec/ports.i"
  55.         include        "intuition/intuition.i"
  56.         include        "intuition/intuitionbase.i"
  57.         include        "intuition/intuition_lib.i"
  58.         include        "graphics/graphics_lib.i"
  59.         include        "libraries/dos_lib.i"
  60.         include        "libraries/dos.i"
  61.         include        "libraries/dosextens.i"
  62.         include        "hardware/intbits.i"
  63.         include        "devices/trackdisk.i"
  64.  
  65. * My Unit structure
  66. MU_Unit        =0            ; Address of drive-unit
  67. MU_Number    =4            ; Track number
  68. MU_SIZE        =6
  69.  
  70. DB        EQUR        A4
  71.  
  72.  dcDeclare    A4
  73.  dcAPtr        TDProcess        ; This process 
  74.  dcAPtr        WBenchMsg        ; Message from Workbench
  75.  dcAPtr        GraphBase
  76.  dcAPtr        IntuiBase
  77.  dcAPtr        DWindow            ; APtr to Window
  78.  dcAPtr        Rp            ; APtr to RastPort
  79.  dcAPtr        Up            ; APtr to UserPort
  80.  dcAPtr        Font            ; APtr to Topaz-80
  81.  dcWord        StrLength
  82.  dcArea        IOExtTD,IOTD_SIZE    ; IOExtTD structure
  83.  dcArea        TDPort,MP_SIZE        ; MessagePort structure
  84.  dcArea        TDInterrupt,IS_SIZE    ; Interrupt structure
  85.  dcArea        Drive0,MU_SIZE
  86.  dcArea        Drive1,MU_SIZE
  87.  dcArea        Drive2,MU_SIZE
  88.  dcArea        Drive3,MU_SIZE
  89.  dcWord        yPos            ; y-position of text in window
  90.  dcWord        Height            ; Height of window
  91.  dcWord        xPos            ; x-position of text in window
  92.  dcWord        Width            ; Width of window
  93.  dcWord        UOffset            ; Offset into unit structure (to get to track indicator)
  94.  dcWord        Version            ; Kickstart version ID
  95.  dcArea        TDDrives,32        ; Yes, 32.
  96.  dcEnd
  97.  
  98. Start        DetachSingle    <'TD'>,4000,0
  99.         dcAlloc                    ; Allocate memory for variables
  100.         dcReset                    ; Clear the memory
  101.         lea        TxtAttr(PC),A0        ; To avoid reloc32 hunks
  102.         lea        FontName(PC),A1
  103.         move.l        A1,(A0)
  104.         Prepare        Exec_Call
  105.         lea        Settings1.3H(PC),A0
  106.         cmp.w        #34,LIB_VERSION(A6)
  107.         ble.S        1$
  108.         lea        Settings2.0H(PC),A0
  109. 1$        movem.l        (A0),D0-D1
  110.         movem.l        D0-D1,Version(DB)    ; Initialize variables
  111.         suba.l        A1,A1
  112.         CallLib        FindTask        ; Find us
  113.         move.l        D0,TDProcess(DB)
  114.         move.l        D0,A2
  115.         tst.l        pr_CLI(A2)
  116.         bne.S        GetLibs            ; Also works after segment-splitting
  117.         lea        pr_MsgPort(A2),A0
  118.         CallLib        WaitPort        ; wait for a message
  119.         lea        pr_MsgPort(A2),A0
  120.         CallLib        GetMsg            ; then get it
  121.         move.l        D0,WBenchMsg(DB)    ; save it for later reply
  122. GetLibs        lea        GfxName(PC),A1
  123.         CallLib        OldOpenLibrary
  124.         move.l        D0,GraphBase(DB)
  125.         beq        Error
  126.         lea        IntuiName(PC),A1
  127.         CallLib        OldOpenLibrary
  128.         move.l        D0,IntuiBase(DB)
  129.         beq        Error
  130. GetIOExtTD    moveq        #-1,D0
  131.         CallLib        AllocSignal
  132.         cmpi.b        #-1,D0
  133.         beq        Error
  134.         lea        TDPort(DB),A0
  135.         clr.b        MP+LN_PRI(A0)            ; MsgPort->mp_Node.ln_Pri =Pri
  136.         move.b        #NT_MSGPORT,MP+LN_TYPE(A0)    ; MsgPort->mp_Node.ln_Type=NT_MSGPORT
  137.         move.b        #PA_SIGNAL,MP_FLAGS(A0)        ; MsgPort->mp_Flags      =PA_SIGNAL
  138.         move.b        D0,MP_SIGBIT(A0)        ; MsgPort->mp_SigBit      =MPSigBit
  139.         lea        TDPort(DB),A1
  140.         move.l        TDProcess(DB),MP_SIGTASK(A1)    ; MsgPort->mp_SigTask     =FindTask(0)
  141.         CallLib        AddPort
  142.         lea        IOExtTD(DB),A1
  143.         move.b        #NT_MESSAGE,IO+MN+LN_TYPE(A1)    ; IOExtTD->io_Message.mn_Node.ln_Type=NT_MESSAGE
  144.         clr.b        IO+MN+LN_PRI(A1)        ; IOExtTD->io_Message.mn_Node.ln_Pri =0
  145.         lea        TDPort(DB),A0
  146.         move.l        A0,IO+MN_REPLYPORT(A1)        ; IOExtTD->io_Message.mn_ReplyPort   =Rep
  147. GetUnits    lea        Drive0(DB),A2        ; See which drives are available
  148.         lea        TDDrives(DB),A3
  149.         moveq        #0,D2
  150.         moveq        #0,D3
  151. 1$;        clr.l        MU_Unit(A2)
  152.         not.w        MU_Number(A2)        ; Was 0, now -1
  153.         move.l        D2,D0
  154.         moveq        #0,D1
  155.         lea        TrackName(PC),A0
  156.         lea        IOExtTD(DB),A1
  157.         CallLib        OpenDevice
  158.         tst.l        D0
  159.         bne.S        2$
  160.         move.b        #'D',(A3)+        ; Create 'DFx: ?? '
  161.         move.b        #'F',(A3)+
  162.         move.b        #'0',(A3)
  163.         add.b        D2,(A3)+
  164.         move.b        #':',(A3)+
  165.         move.b        #' ',(A3)+
  166.         addq.l        #2,A3
  167.         move.b        #' ',(A3)+
  168.         addq.w        #1,D3
  169.         lea        IOExtTD(DB),A1        ; Oh yeah, drive is available
  170.         move.l        IO_UNIT(A1),MU_Unit(A2)    ; Store address of unit-structure
  171.         CallLib        CloseDevice        ; Close Unit again
  172. 2$        subq.l        #MU_SIZE,A2
  173.         addq.l        #1,D2
  174.         cmp.w        #4,D2
  175.         blt.S        1$
  176.         move.w        D3,D0
  177.         mulu        #7,D3
  178.         subq.w        #1,D0
  179.         bmi        Error
  180.         add.w        D0,D3
  181.         move.w        D3,StrLength(DB)
  182.         mulu        #8,D3
  183.         add.w        D3,Width(DB)
  184. GetWindow    Prepare        Intuition_Call
  185.         CallLib        OpenWorkBench
  186.         tst.l        D0
  187.         beq        Error
  188.         move.l        D0,A1
  189.         move.w        sc_Width(A1),D0
  190.         sub.w        Width(DB),D0
  191.         lsr.w        #1,D0
  192.         lea        NW(PC),A0
  193.         move.w        D0,nw_LeftEdge(A0)    ; Center the window
  194.         moveq        #0,D1
  195.         move.b        sc_BarHeight(A1),D1
  196.         tst.w        Version(DB)
  197.         beq.S        1$
  198.         addq.w        #1,D1            ; Because of newlook
  199. 1$        move.w        D1,Height(DB)
  200.         subq.w        #7,D1
  201.         lsr.w        #1,D1
  202.         addq.w        #6,D1
  203.         move.w        D1,yPos(DB)
  204.         move.w        Width(DB),nw_Width(A0)
  205.         move.w        Height(DB),nw_Height(A0)
  206.         CallLib        OpenWindow
  207.         move.l        D0,DWindow(DB)
  208.         beq        Error
  209.         move.l        D0,A0
  210.         move.l        wd_RPort(A0),Rp(DB)
  211.         move.l        wd_UserPort(A0),Up(DB)    ; UserPort
  212.         move.l        DWindow(DB),A0
  213.         suba.l        A1,A1
  214.         lea        ScrTitle(PC),A2
  215.         CallLib        SetWindowTitles
  216.         Prepare        Gfx_Call
  217.         move.l        Rp(DB),A2
  218.         moveq        #0,D0            ; Assume 1.3 colors
  219.         moveq        #1,D2
  220.         tst.w        Version(DB)
  221.         beq.S        2$
  222.         exg        D0,D2            ; Well, use 2.0 colors
  223. 2$        move.l        A2,A1
  224.         CallLib        SetAPen
  225.         move.l        A2,A1
  226.         move.w        D2,D0
  227.         CallLib        SetBPen
  228.         move.l        A2,A1
  229.         moveq        #RP_JAM2,D0
  230.         CallLib        SetDrMd
  231.         lea        TxtAttr(PC),A0
  232.         CallLib        OpenFont
  233.         move.l        D0,Font(DB)
  234.         beq.S        Error
  235.         move.l        D0,A0
  236.         move.l        A2,A1
  237.         CallLib        SetFont
  238. SetInterrupt    Prepare        Exec_Call
  239.         lea        TDInterrupt(DB),A1        ; Start vertical-blanking interrupt-server
  240.         move.b        #NT_INTERRUPT,LN_TYPE(A1)    ; TDInterrupt->is_Node.ln_Type=NT_INTERRUPT
  241.         lea        TDIntName(PC),A0
  242.         move.l        A0,LN_NAME(A1)            ; TDInterrupt->is_Node.ln_Name=TDIntName
  243.         lea        TDIntServer(PC),A0
  244.         move.l        A0,IS_CODE(A1)            ; TDInterrupt->is_Code          =TDIntServer
  245.         move.l        DB,IS_DATA(A1)            ; TDInterrupt->is_Data          =DB
  246.         moveq        #INTB_VERTB,D0
  247.         CallLib        AddIntServer
  248.         bra        Main
  249.  
  250. Exit
  251. Error
  252. FreeInterrupt    Prepare        Exec_Call
  253.         lea        TDInterrupt(DB),A1
  254.         tst.l        IS_CODE(A1)        ; If this is set then server has been added
  255.         beq.S        FreeFont
  256.         moveq        #INTB_VERTB,D0
  257.         CallLib        RemIntServer
  258. FreeFont    Prepare        Gfx_Call
  259.         move.l        Font(DB),D0
  260.         beq.S        FreeWindow
  261.         move.l        D0,A1
  262.         CallLib        CloseFont
  263. FreeWindow    Prepare        Intuition_Call
  264.         move.l        DWindow(DB),D0
  265.         beq.S        FreePort
  266.         move.l        D0,A0
  267.         CallLib        CloseWindow
  268. FreePort    Prepare        Exec_Call
  269.         lea        TDPort(DB),A2
  270.         tst.b        MP_SIGBIT(A2)        ; If we have bit we also have port
  271.         beq.S        FreeIntui
  272.         move.l        A2,A1
  273.         CallLib        RemPort
  274.         moveq        #0,D0
  275.         move.b        MP_SIGBIT(A2),D0
  276.         CallLib        FreeSignal
  277. FreeIntui    move.l        IntuiBase(DB),D0
  278.         beq.S        FreeGfx
  279.         move.l        D0,A1
  280.         CallLib        CloseLibrary
  281. FreeGfx        move.l        GraphBase(DB),D0
  282.         beq.S        ReplyWB
  283.         move.l        D0,A1
  284.         CallLib        CloseLibrary
  285. ReplyWB        move.l        WBenchMsg(DB),D2
  286.         beq.S        AllDone
  287.         CallLib        Forbid
  288.         move.l        D2,A1
  289.         CallLib        ReplyMsg        ; Reply WBenchMessage if we are started from WB
  290. AllDone        dcFree
  291.         moveq        #0,D0
  292.         rts
  293.  
  294. Main
  295. EventLoop    move.l        Up(DB),A0
  296.         moveq        #0,D0
  297.         moveq        #0,D1
  298.         move.b        MP_SIGBIT(A0),D1
  299.         bset        D1,D0
  300.         bset        #SIGBREAKB_CTRL_D,D0
  301.         Prepare        Exec_Call
  302.         CallLib        Wait
  303.         btst        #SIGBREAKB_CTRL_D,D0
  304.         beq.S        GetNextMsg
  305.         lea        TDDrives+5(DB),A1
  306.         lea        Drive0(DB),A0
  307.         moveq        #'0',D2
  308.         moveq        #0,D1
  309. 1$        move.w        MU_Number(A0),D0
  310.         bmi.S        2$
  311.         ext.l        D0
  312.         divu        #10,D0
  313.         add.w        D2,D0
  314.         move.b        D0,(A1)
  315.         swap        D0
  316.         add.w        D2,D0
  317.         move.b        D0,1(A1)
  318.         addq.l        #8,A1
  319. 2$        subq.l        #MU_SIZE,A0
  320.         addq.w        #1,D1
  321.         cmp.w        #4,D1
  322.         blt.S        1$
  323.         Call        UpdateDisplay
  324.         bra.S        EventLoop
  325.  
  326. GetNextMsg    move.l        Up(DB),A0
  327.         Prepare        Exec_Call
  328.         CallLib        GetMsg
  329.         tst.l        D0
  330.         beq.S        EventLoop
  331.         move.l        D0,A1
  332.         move.l        im_Class(A1),D2
  333.         CallLib        ReplyMsg
  334.         cmp.l        #CLOSEWINDOW,D2
  335.         beq        Exit
  336.         tst.w        Version(DB)        ; No need to change color
  337.         beq.S        3$            ; under 1.2/1.3
  338.         cmp.l        #ACTIVEWINDOW,D2
  339.         bne.S        1$
  340.         Call        GetBackColor
  341.         move.w        D0,D2
  342.         Call        GetFrontColor
  343.         bra.S        2$
  344. 1$        cmp.l        #INACTIVEWINDOW,D2
  345.         bne.S        3$
  346.         moveq        #0,D2
  347.         moveq        #1,D0
  348. 2$        Prepare        Gfx_Call
  349.         move.l        Rp(DB),A1
  350.         CallLib        SetAPen
  351.         move.w        D2,D0
  352.         move.l        Rp(DB),A1
  353.         CallLib        SetBPen
  354. 3$        Call        UpdateDisplay        ; Do some refreshing
  355.         bra.S        GetNextMsg
  356.  
  357. UpdateDisplay    Prepare        Gfx_Call
  358.         move.l        Rp(DB),A1
  359.         move.w        xPos(DB),D0
  360.         move.w        yPos(DB),D1
  361.         CallLib        Move
  362.         lea        TDDrives(DB),A0
  363.         move.l        Rp(DB),A1
  364.         move.w        StrLength(DB),D0
  365.         CallLib        Text
  366.         rts
  367.  
  368. *»»» Call:    A1 = DB
  369. *»»» Inside the server the registers D0-D1/A0-A1/A5-A6 can be used
  370. *»»» without restoring them on exit
  371. TDIntServer    Push        D2/DB
  372.         move.l        A1,DB
  373.         moveq        #0,D2            ; Don't signal
  374.         lea        Drive3(DB),A0
  375.         moveq        #3,D1
  376. 1$        move.l        MU_Unit(A0),D0
  377.         beq.S        2$            ; Does drive exist
  378.         move.l        D0,A1
  379.         add.w        UOffset(DB),A1
  380.         move.w        (A1),D0
  381.         asr.w        #1,D0
  382.         cmp.w        MU_Number(A0),D0
  383.         beq.S        2$
  384.         move.w        D0,MU_Number(A0)
  385.         moveq        #1,D2            ; Do signal
  386. 2$        addq.l        #MU_SIZE,A0
  387.         dbf        D1,1$
  388.         tst.w        D2
  389.         beq.S        3$
  390.         move.l        TDProcess(DB),A1
  391.         move.l        #SIGBREAKF_CTRL_D,D0
  392.         Prepare        Exec_Call
  393.         CallLib        Signal
  394. 3$        Pop        D2/DB
  395.         rts
  396.  
  397.  
  398. *»»» These routines return the colors that Kickstart 2.x uses for
  399. *»»» title-text and window-frames in active windows. Perhaps I
  400. *»»» am using system-private values here - I didn't have access
  401. *»»» Kickstart 2.x includes and autodocs when I wrote this.
  402. *»»»
  403. *»»» Return:    D0 = Color used for title-text in active windows.
  404. GetFrontColor    moveq        #12,D0
  405.         bra.S        GetColor
  406. *»»» Return:    D0 = Color used for window-frames in active windows.
  407. GetBackColor    moveq        #10,D0
  408. GetColor    move.l        DWindow(DB),A0
  409.         move.l        wd_WScreen(A0),A0
  410.         move.l        $1DE+4(A0),A0
  411.         move.w        0(A0,D0.W),D0
  412.         rts
  413.  
  414. GfxName        dc.b        'graphics.library',0
  415. IntuiName    dc.b        'intuition.library',0
  416. TrackName    dc.b        'trackdisk.device',0
  417. TDIntName    dc.b        'TD Interrupt',0
  418. ScrTitle    dc.b        'TD V2.0 1991 by Preben Nielsen.',0
  419.         EVEN
  420.  
  421. Kick1        =0
  422. *»»» Defines for hires under kickstart 1.2-1.3 (and below ?)
  423. Offset1.3    =74
  424. Width1.3H    =85        ; Gadget size
  425. xPos1.3H    =30
  426.  
  427. Kick2        =1
  428. *»»» Defines for hires under kickstart 2.0 (and up ?)
  429. Offset2.0    =54
  430. Width2.0H    =51        ; Gadget size
  431. xPos2.0H    =23
  432.  
  433. Settings1.3H    dc.w        Kick1,Offset1.3,Width1.3H,xPos1.3H
  434. Settings2.0H    dc.w        Kick2,Offset2.0,Width2.0H,xPos2.0H
  435.  
  436. IDCMP_Flags    =        CLOSEWINDOW|INACTIVEWINDOW|ACTIVEWINDOW
  437. Other_Flags    =        RMBTRAP|WINDOWCLOSE|WINDOWDEPTH|WINDOWDRAG
  438. NW        dc.w        0,0,0,0
  439.         dc.b        0,1
  440.         dc.l        IDCMP_Flags,Other_Flags
  441.         dc.l        0,0,0,0,0
  442.         dc.w        0,0,0,0,WBENCHSCREEN
  443.  
  444. TxtAttr        dc.l        0
  445.         dc.w        TOPAZ_EIGHTY
  446.         dc.b        FS_NORMAL,FPB_ROMFONT
  447. FontName    dc.b        'topaz.font',0
  448.         END
  449.  
  450.